SPSS FREQUENCIES 命令快速教程

作者：Ruben Geert van den Berg 在 SPSS 表格 & SPSS A-Z 下发布

SPSS 的 FREQUENCIES 命令不仅仅用于生成频数表（frequency table）：它也是获取基本图表（charts），如直方图（histograms）和条形图（bar charts）的最简单方法。除此之外，它还提供了百分位数（percentiles）和其他一些统计量（statistics）。我们有充分的理由仔细研究这个无处不在的 SPSS 命令。在本教程中，我们将使用 employees.sav 数据集。

SPSS FREQUENCIES - 基本表格

使用 FREQUENCIES 最基本的方法是简单地生成一个频数表。例如，可以通过运行以下 SPSS 语法行来获得 job_type 的频数表：

frequencies job_type.

默认情况下，此表的行按值升序排序。请注意，当仅显示值标签（value labels）时，这可能不明显。接下来，我们将了解对表行进行排序的不同选项。

SPSS FREQUENCIES - 排序方式

SPSS 默认的按值升序排序可以通过添加 FORMAT 子命令来更改。可能的值包括 AVALUE 和 DVALUE （升序和降序值）或 AFREQ 和 DFREQ （升序和降序频率）。例如，以下语法按频率从最高到最低（是的，这就是众数（mode））对行进行排序。

***按频率降序排列的频数表。
frequencies job_type
/format dfreq.

SPSS FREQUENCIES - 条形图

SPSS 的 FREQUENCIES 命令是为分类变量创建一个或多个条形图的最简单方法。只需添加 BARCHART 子命令即可。请注意，您可以将其与排序顺序结合使用，从而使条形图的条按从最高到最低的频率排序，如下所示。

***创建频数表和条形图，均按降序频率排序。
frequencies job_type
/format dfreq
/barchart.

SPSS FREQUENCIES - 饼图

分类变量的另一种可视化方式是饼图（pie chart）。为了生成它，只需将 PIECHART 子命令添加到 FREQUENCIES。以下语法为 education_type 创建一个饼图。

***为 education_type 创建饼图。
frequencies education_type
/piechart.

SPSS FREQUENCIES - 直方图

频数表、条形图和饼图都可用于度量变量（metric variables）和分类变量，包括字符串变量（string variables）。但是，对于具有许多不同值的度量变量，它们没有用；在这种情况下，表格的行数过多，图形的元素过多。可视化此类变量的理想方法是直方图，通过 HISTOGRAM 子命令获得。除此之外，我们可以通过在 FORMAT 子命令上指定 NOTABLE 来抑制频数表。像这样，以下语法为 monthly_income 生成直方图。

***为 monthly_income 生成直方图（没有表格）。
frequencies monthly_income
/format notable
/histogram.

SPSS FREQUENCIES - 百分位数

SPSS FREQUENCIES 提供了一种获取百分位数的好方法：只需添加 PERCENTILES 子命令，后跟括号中所需的百分位数。以下语法给出一个示例。请记住，百分位数对于名义变量（nominal variables）没有意义。

***计算 monthly_income 的第 25 个、第 50 个和第 75 个百分位数。
frequencies monthly_income
/format notable
/percentiles (25 50,75).

SPSS FREQUENCIES - N 分位数

使用 SPSS FREQUENCIES 可以轻松获得 N 分位数（Ntiles）：只需添加 NTILES 子命令，并在其后的括号中添加 N 分位数的数量。如果要将个案分配到 N 分位数组，请使用 RANK；它创建一个新变量，该变量保存给定变量上每个个案的 N 分位数。以下语法中显示了这两个选项。

***1. 检查 monthly_income 的 N 分位数。
frequencies monthly_income
/format notable
/ntiles (5).

***2. 在数据中创建 monthly_income N 分位数组成员变量。
rank monthly_income/ntiles(5).

SPSS FREQUENCIES - 统计量

SPSS FREQUENCIES 可以计算从 DESCRIPTIVES 获得的所有统计量，以及中位数（median）和众数。请注意，来自 FREQUENCIES 的统计表具有不同的布局，变量在列中，统计量在行中。为了获得它们，请添加 STATISTICS 子命令。与 DESCRIPTIVES 一样，指定 ALL 关键字会返回所有可用的统计量。

***从 monthly_income 获取所有可用的统计量。
frequencies monthly_income
/format notable
/statistics all.

SPSS FREQUENCIES - 多个变量

显然，可以为多个变量运行 FREQUENCIES，可以使用 TO 或 ALL。如果生成多种类型的输出（频数表、图表等），您可以通过在 ORDER 子命令上指定 VARIABLE 或 ANALYSIS 来按变量或输出类型对它们进行排序。

***1. 按变量对输出进行排序。
frequencies education_type to job_type
/format dfreq
/barchart
/order variable.

***2. 按输出类型对输出进行排序（首先是所有变量的表格，然后是所有变量的图表）。
frequencies education_type to job_type
/format dfreq
/barchart
/order analysis.